How to Add a News Filter to Your MT4 Expert Advisor

//+------------------------------------------------------------------+
//| SMT_NewsFilter.mqh - news filter for MT4 and MT5                 |
//| Data: https://showmytrades.com/api/public/calendar/v1 (free)     |
//| Docs: https://showmytrades.com/docs/api/economic-calendar        |
//| Setup: Tools > Options > Expert Advisors > Allow WebRequest for  |
//|        https://showmytrades.com                                  |
//+------------------------------------------------------------------+
#property strict

input string SMT_Currencies     = "EUR,USD"; // News: currencies (comma-separated, empty = all)
input string SMT_Impact         = "high";    // News: impact (high | high,medium | all)
input int    SMT_MinutesBefore  = 30;        // News: pause before a release (minutes)
input int    SMT_MinutesAfter   = 30;        // News: pause after a release (minutes)
input int    SMT_RefreshMinutes = 15;        // News: download interval (minutes, min 15)

datetime smt_eventTime[];
string   smt_eventTitle[];
datetime smt_nextDownload = 0;

//--- everything after the n-th comma (the CSV title, which may itself contain commas)
string SMT_AfterComma(const string line, const int n)
{
   int pos = -1;
   for(int i = 0; i < n; i++)
   {
      pos = StringFind(line, ",", pos + 1);
      if(pos < 0) return "";
   }
   string rest = StringSubstr(line, pos + 1);
   StringReplace(rest, "\"\"", "\"");
   if(StringLen(rest) >= 2 && StringGetCharacter(rest, 0) == '"')
      rest = StringSubstr(rest, 1, StringLen(rest) - 2);
   return rest;
}

//--- downloads the next 2 days (the window also covers the last 6 hours)
bool SMT_Download()
{
   string url = "https://showmytrades.com/api/public/calendar/v1?format=csv&days=2&impact=" + SMT_Impact;
   if(StringLen(SMT_Currencies) > 0) url += "&currency=" + SMT_Currencies;

   char   post[], result[];
   string headers;
   ResetLastError();
   int status = WebRequest("GET", url, "", NULL, 10000, post, 0, result, headers);
   if(status != 200)
   {
      Print("[SMT] calendar download failed: HTTP ", status, ", error ", GetLastError(),
            ". Is https://showmytrades.com in Tools > Options > Expert Advisors > Allow WebRequest?");
      smt_nextDownload = TimeCurrent() + 60; // retry in a minute
      return false;
   }

   string body = CharArrayToString(result, 0, WHOLE_ARRAY, CP_UTF8);
   string lines[];
   int n = StringSplit(body, '\n', lines);

   ArrayResize(smt_eventTime, 0);
   ArrayResize(smt_eventTitle, 0);
   for(int i = 1; i < n; i++) // line 0 is the header
   {
      string f[];
      if(StringSplit(lines[i], ',', f) < 8) continue;
      int k = ArraySize(smt_eventTime);
      ArrayResize(smt_eventTime, k + 1);
      ArrayResize(smt_eventTitle, k + 1);
      smt_eventTime[k]  = (datetime)StringToInteger(f[0]);      // Unix seconds, UTC
      smt_eventTitle[k] = f[2] + " " + f[3] + ": " + SMT_AfterComma(lines[i], 7);
   }
   smt_nextDownload = TimeCurrent() + MathMax(SMT_RefreshMinutes, 15) * 60;
   Print("[SMT] calendar: ", ArraySize(smt_eventTime), " events loaded");
   return true;
}

//--- true while a release is within the pause window; reason tells which one
bool SMT_IsNewsTime(string &reason)
{
   reason = "";
   if(MQLInfoInteger(MQL_TESTER)) return false;   // no network in the tester
   if(TimeCurrent() >= smt_nextDownload) SMT_Download();

   datetime now = TimeGMT();
   for(int i = 0; i < ArraySize(smt_eventTime); i++)
   {
      if(now >= smt_eventTime[i] - SMT_MinutesBefore * 60 && now <= smt_eventTime[i] + SMT_MinutesAfter * 60)
      {
         reason = smt_eventTitle[i];
         return true;
      }
   }
   return false;
}

#include <SMT_NewsFilter.mqh>

void OnTick()
{
   string news;
   if(SMT_IsNewsTime(news))
   {
      Comment("News filter active: ", news);
      return;                       // no new entries during the news window
   }
   Comment("");
   // ... your entry logic ...
}