如何为您的 MT4 EA 添加新闻过滤器

//+------------------------------------------------------------------+
//| SMT_NewsFilter.mqh - MT4 和 MT5 新闻过滤器
//| 数据：https://showmytrades.com/api/public/calendar/v1（免费）
//| 文档：https://showmytrades.com/docs/api/economic-calendar
//| 设置：工具 > 选项 > 智能交易系统 > 允许 WebRequest 访问
//|       https://showmytrades.com
//+------------------------------------------------------------------+
#property strict

input string SMT_Currencies     = "EUR,USD"; // 新闻：货币（逗号分隔，留空 = 全部）
input string SMT_Impact         = "high";    // 新闻：影响级别（high | high,medium | all）
input int    SMT_MinutesBefore  = 30;        // 新闻：公布前暂停（分钟）
input int    SMT_MinutesAfter   = 30;        // 新闻：公布后暂停（分钟）
input int    SMT_RefreshMinutes = 15;        // 新闻：下载间隔（分钟，最少 15）

datetime smt_eventTime[];
string   smt_eventTitle[];
datetime smt_nextDownload = 0;
long     smt_serverTime   = 0;     // 上次下载时的服务器 UTC 时间（Unix 秒）
uint     smt_syncTick     = 0;     // 当时的 GetTickCount()
bool     smt_clockSynced  = false;

//--- 真实的 UTC 时间：服务器时钟加上自下载以来经过的毫秒数，
//--- 用 GetTickCount() 计数，它不受时区、夏令时和电脑时钟校正的影响
//--- （uint 减法在计数器回绕后依然正确）。
//--- 首次下载之前退回使用 TimeGMT()。绝不用 TimeCurrent()：
//--- 经纪商的 GMT 偏移未知，而且会随夏令时跳变。
datetime SMT_Now()
{
   if(!smt_clockSynced) return TimeGMT();
   uint elapsedMs = GetTickCount() - smt_syncTick;
   return (datetime)(smt_serverTime + elapsedMs / 1000);
}

//--- 经纪商时钟与 UTC 的差值，单位为秒（7200 = GMT+2）。它本身就很有用：
//--- 大多数 EA 从来不知道这个值。TimeCurrent() 是最后一个 tick 的时间，
//--- 所以请在开市时读取，不要在周末读取。
int SMT_BrokerGmtOffsetSeconds()
{
   return (int)(TimeCurrent() - SMT_Now());
}

//--- 第 n 个逗号之后的全部内容（CSV 的标题，标题本身可能含有逗号）
string SMT_AfterComma(const string line, const int n)
{
   int pos = -1;
   for(int i = 0; i < n; i++)
   {
      pos = StringFind(line, ",", pos + 1);
      if(pos < 0) return "";
   }
   string rest = StringSubstr(line, pos + 1);
   StringReplace(rest, "\"\"", "\"");
   if(StringLen(rest) >= 2 && StringGetCharacter(rest, 0) == '"')
      rest = StringSubstr(rest, 1, StringLen(rest) - 2);
   return rest;
}

//--- 下载未来 2 天的数据（时间窗口也包含过去 6 小时）
bool SMT_Download()
{
   string url = "https://showmytrades.com/api/public/calendar/v1?format=csv&days=2&impact=" + SMT_Impact;
   if(StringLen(SMT_Currencies) > 0) url += "&currency=" + SMT_Currencies;

   char   post[], result[];
   string headers;
   ResetLastError();
   int status = WebRequest("GET", url, "", NULL, 10000, post, 0, result, headers);
   if(status != 200)
   {
      Print("[SMT] 日历下载失败：HTTP ", status, "，错误 ", GetLastError(),
            "。https://showmytrades.com 是否已添加到 工具 > 选项 > 智能交易系统 > 允许 WebRequest？");
      smt_nextDownload = TimeCurrent() + 60; // 一分钟后重试
      return false;
   }

   string body = CharArrayToString(result, 0, WHOLE_ARRAY, CP_UTF8);
   string lines[];
   int n = StringSplit(body, '\n', lines);

   ArrayResize(smt_eventTime, 0);
   ArrayResize(smt_eventTitle, 0);
   for(int i = 1; i < n; i++) // 第 0 行是表头
   {
      // 最后一行 "# server_time=1760702400 server_time_iso=..."：服务器的 UTC 时钟
      if(StringFind(lines[i], "# server_time=") == 0)
      {
         long serverTime = StringToInteger(StringSubstr(lines[i], 14, 10));
         if(serverTime > 0)
         {
            smt_serverTime  = serverTime;
            smt_syncTick    = GetTickCount();
            smt_clockSynced = true;
         }
         continue;
      }
      string f[];
      if(StringSplit(lines[i], ',', f) < 8) continue;
      int k = ArraySize(smt_eventTime);
      ArrayResize(smt_eventTime, k + 1);
      ArrayResize(smt_eventTitle, k + 1);
      smt_eventTime[k]  = (datetime)StringToInteger(f[0]);      // Unix 秒，UTC
      smt_eventTitle[k] = f[2] + " " + f[3] + ": " + SMT_AfterComma(lines[i], 7);
   }
   smt_nextDownload = TimeCurrent() + MathMax(SMT_RefreshMinutes, 15) * 60;
   Print("[SMT] 日历：已加载 ", ArraySize(smt_eventTime), " 个事件。当前 UTC ",
         TimeToString(SMT_Now(), TIME_DATE|TIME_MINUTES), "，经纪商时钟为 GMT",
         (SMT_BrokerGmtOffsetSeconds() >= 0 ? "+" : ""), DoubleToString(SMT_BrokerGmtOffsetSeconds() / 3600.0, 1));
   return true;
}

//--- 有数据公布处于暂停窗口内时返回 true；reason 说明是哪一条
bool SMT_IsNewsTime(string &reason)
{
   reason = "";
   if(MQLInfoInteger(MQL_TESTER)) return false;   // 测试器中没有网络
   if(TimeCurrent() >= smt_nextDownload) SMT_Download();

   datetime now = SMT_Now();
   for(int i = 0; i < ArraySize(smt_eventTime); i++)
   {
      if(now >= smt_eventTime[i] - SMT_MinutesBefore * 60 && now <= smt_eventTime[i] + SMT_MinutesAfter * 60)
      {
         reason = smt_eventTitle[i];
         return true;
      }
   }
   return false;
}

#include <SMT_NewsFilter.mqh>

void OnTick()
{
   string news;
   if(SMT_IsNewsTime(news))
   {
      Comment("新闻过滤生效中：", news);
      return;                       // 新闻窗口内不开新仓
   }
   Comment("");
   // ... 您的入场逻辑 ...
}