So baust du einen News-Filter in deinen MT4-Expert-Advisor ein

//+------------------------------------------------------------------+
//| SMT_NewsFilter.mqh - News-Filter für MT4 und MT5                 |
//| Daten: https://showmytrades.com/api/public/calendar/v1 (gratis)  |
//| Doku: https://showmytrades.com/docs/api/economic-calendar        |
//| Setup: Extras > Optionen > Expert Advisors > WebRequest für      |
//|        https://showmytrades.com erlauben                         |
//+------------------------------------------------------------------+
#property strict

input string SMT_Currencies     = "EUR,USD"; // News: Währungen (kommagetrennt, leer = alle)
input string SMT_Impact         = "high";    // News: Wichtigkeit (high | high,medium | all)
input int    SMT_MinutesBefore  = 30;        // News: Pause vor einer Veröffentlichung (Minuten)
input int    SMT_MinutesAfter   = 30;        // News: Pause nach einer Veröffentlichung (Minuten)
input int    SMT_RefreshMinutes = 15;        // News: Download-Intervall (Minuten, min. 15)

datetime smt_eventTime[];
string   smt_eventTitle[];
datetime smt_nextDownload = 0;
long     smt_serverTime   = 0;     // UTC-Zeit des Servers (Unix-Sekunden) beim letzten Download
uint     smt_syncTick     = 0;     // GetTickCount() im selben Moment
bool     smt_clockSynced  = false;

//--- die echte UTC-Zeit: die Uhr des Servers plus die seit dem Download vergangenen
//--- Millisekunden, gezählt mit GetTickCount(). Der Zähler kennt keine Zeitzonen, keine
//--- Sommerzeit und keine Uhrkorrekturen auf dem Rechner (die uint-Subtraktion übersteht
//--- auch seinen Überlauf). Vor dem ersten Download dient TimeGMT() als Ersatz. Nie
//--- TimeCurrent(): Der GMT-Offset des Brokers ist unbekannt und springt mit der Sommerzeit.
datetime SMT_Now()
{
   if(!smt_clockSynced) return TimeGMT();
   uint elapsedMs = GetTickCount() - smt_syncTick;
   return (datetime)(smt_serverTime + elapsedMs / 1000);
}

//--- Abstand der Broker-Uhr zu UTC in Sekunden (7200 = GMT+2). Auch für sich allein
//--- nützlich: Die meisten EAs kennen diesen Wert nie. TimeCurrent() ist die Zeit des
//--- letzten Ticks, also bei geöffnetem Markt auslesen, nicht am Wochenende.
int SMT_BrokerGmtOffsetSeconds()
{
   return (int)(TimeCurrent() - SMT_Now());
}

//--- alles nach dem n-ten Komma (der CSV-Titel, der selbst Kommas enthalten kann)
string SMT_AfterComma(const string line, const int n)
{
   int pos = -1;
   for(int i = 0; i < n; i++)
   {
      pos = StringFind(line, ",", pos + 1);
      if(pos < 0) return "";
   }
   string rest = StringSubstr(line, pos + 1);
   StringReplace(rest, "\"\"", "\"");
   if(StringLen(rest) >= 2 && StringGetCharacter(rest, 0) == '"')
      rest = StringSubstr(rest, 1, StringLen(rest) - 2);
   return rest;
}

//--- lädt die nächsten 2 Tage herunter (das Fenster deckt auch die letzten 6 Stunden ab)
bool SMT_Download()
{
   string url = "https://showmytrades.com/api/public/calendar/v1?format=csv&days=2&impact=" + SMT_Impact;
   if(StringLen(SMT_Currencies) > 0) url += "&currency=" + SMT_Currencies;

   char   post[], result[];
   string headers;
   ResetLastError();
   int status = WebRequest("GET", url, "", NULL, 10000, post, 0, result, headers);
   if(status != 200)
   {
      Print("[SMT] calendar download failed: HTTP ", status, ", error ", GetLastError(),
            ". Is https://showmytrades.com in Tools > Options > Expert Advisors > Allow WebRequest?");
      smt_nextDownload = TimeCurrent() + 60; // neuer Versuch in einer Minute
      return false;
   }

   string body = CharArrayToString(result, 0, WHOLE_ARRAY, CP_UTF8);
   string lines[];
   int n = StringSplit(body, '\n', lines);

   ArrayResize(smt_eventTime, 0);
   ArrayResize(smt_eventTitle, 0);
   for(int i = 1; i < n; i++) // Zeile 0 ist die Kopfzeile
   {
      // letzte Zeile "# server_time=1760702400 server_time_iso=...": die UTC-Uhr des Servers
      if(StringFind(lines[i], "# server_time=") == 0)
      {
         long serverTime = StringToInteger(StringSubstr(lines[i], 14, 10));
         if(serverTime > 0)
         {
            smt_serverTime  = serverTime;
            smt_syncTick    = GetTickCount();
            smt_clockSynced = true;
         }
         continue;
      }
      string f[];
      if(StringSplit(lines[i], ',', f) < 8) continue;
      int k = ArraySize(smt_eventTime);
      ArrayResize(smt_eventTime, k + 1);
      ArrayResize(smt_eventTitle, k + 1);
      smt_eventTime[k]  = (datetime)StringToInteger(f[0]);      // Unix-Sekunden, UTC
      smt_eventTitle[k] = f[2] + " " + f[3] + ": " + SMT_AfterComma(lines[i], 7);
   }
   smt_nextDownload = TimeCurrent() + MathMax(SMT_RefreshMinutes, 15) * 60;
   Print("[SMT] calendar: ", ArraySize(smt_eventTime), " events loaded. UTC now ",
         TimeToString(SMT_Now(), TIME_DATE|TIME_MINUTES), ", broker clock is GMT",
         (SMT_BrokerGmtOffsetSeconds() >= 0 ? "+" : ""), DoubleToString(SMT_BrokerGmtOffsetSeconds() / 3600.0, 1));
   return true;
}

//--- true, solange eine Veröffentlichung im Pausenfenster liegt; reason sagt, welche
bool SMT_IsNewsTime(string &reason)
{
   reason = "";
   if(MQLInfoInteger(MQL_TESTER)) return false;   // kein Netzwerk im Tester
   if(TimeCurrent() >= smt_nextDownload) SMT_Download();

   datetime now = SMT_Now();
   for(int i = 0; i < ArraySize(smt_eventTime); i++)
   {
      if(now >= smt_eventTime[i] - SMT_MinutesBefore * 60 && now <= smt_eventTime[i] + SMT_MinutesAfter * 60)
      {
         reason = smt_eventTitle[i];
         return true;
      }
   }
   return false;
}

#include <SMT_NewsFilter.mqh>

void OnTick()
{
   string news;
   if(SMT_IsNewsTime(news))
   {
      Comment("News filter active: ", news);
      return;                       // keine neuen Einstiege im News-Fenster
   }
   Comment("");
   // ... deine Einstiegslogik ...
}