MT4のEAにニュースフィルターを追加する方法

//+------------------------------------------------------------------+
//| SMT_NewsFilter.mqh - MT4・MT5用ニュースフィルター
//| データ：https://showmytrades.com/api/public/calendar/v1（無料）
//| ドキュメント：https://showmytrades.com/docs/api/economic-calendar
//| 設定：ツール > オプション > エキスパートアドバイザ >
//|       WebRequestを許可するURLリストに https://showmytrades.com を追加
//+------------------------------------------------------------------+
#property strict

input string SMT_Currencies     = "EUR,USD"; // ニュース：通貨（カンマ区切り、空欄 = すべて）
input string SMT_Impact         = "high";    // ニュース：重要度（high | high,medium | all）
input int    SMT_MinutesBefore  = 30;        // ニュース：発表前の停止時間（分）
input int    SMT_MinutesAfter   = 30;        // ニュース：発表後の停止時間（分）
input int    SMT_RefreshMinutes = 15;        // ニュース：ダウンロード間隔（分、最小15）

datetime smt_eventTime[];
string   smt_eventTitle[];
datetime smt_nextDownload = 0;
long     smt_serverTime   = 0;     // 前回ダウンロード時のサーバーのUTC時刻（Unix秒）
uint     smt_syncTick     = 0;     // その時点のGetTickCount()
bool     smt_clockSynced  = false;

//--- 本当のUTC時刻：サーバーの時刻に、ダウンロードからの経過ミリ秒を足したもの。
//--- 経過時間はGetTickCount()で数えるので、パソコンのタイムゾーン、夏時間、
//--- 時計の補正の影響を受けない（カウンターが一周してもuintの引き算で正しく求まる）。
//--- 最初のダウンロードまではTimeGMT()で代用する。TimeCurrent()は使わない：
//--- ブローカーのGMTオフセットは分からず、夏時間で変わるため。
datetime SMT_Now()
{
   if(!smt_clockSynced) return TimeGMT();
   uint elapsedMs = GetTickCount() - smt_syncTick;
   return (datetime)(smt_serverTime + elapsedMs / 1000);
}

//--- ブローカーの時計とUTCの差（秒、7200 = GMT+2）。これ単体でも便利：
//--- ほとんどのEAはこの値を知らない。TimeCurrent()は最後のティックの時刻なので、
//--- 週末ではなく、市場が開いているあいだに読むこと。
int SMT_BrokerGmtOffsetSeconds()
{
   return (int)(TimeCurrent() - SMT_Now());
}

//--- n番目のカンマより後ろすべて（CSVのタイトル。タイトル自体にカンマを含むことがある）
string SMT_AfterComma(const string line, const int n)
{
   int pos = -1;
   for(int i = 0; i < n; i++)
   {
      pos = StringFind(line, ",", pos + 1);
      if(pos < 0) return "";
   }
   string rest = StringSubstr(line, pos + 1);
   StringReplace(rest, "\"\"", "\"");
   if(StringLen(rest) >= 2 && StringGetCharacter(rest, 0) == '"')
      rest = StringSubstr(rest, 1, StringLen(rest) - 2);
   return rest;
}

//--- 今後2日分をダウンロード（範囲には直近6時間も含まれる）
bool SMT_Download()
{
   string url = "https://showmytrades.com/api/public/calendar/v1?format=csv&days=2&impact=" + SMT_Impact;
   if(StringLen(SMT_Currencies) > 0) url += "&currency=" + SMT_Currencies;

   char   post[], result[];
   string headers;
   ResetLastError();
   int status = WebRequest("GET", url, "", NULL, 10000, post, 0, result, headers);
   if(status != 200)
   {
      Print("[SMT] calendar download failed: HTTP ", status, ", error ", GetLastError(),
            ". Is https://showmytrades.com in Tools > Options > Expert Advisors > Allow WebRequest?");
      smt_nextDownload = TimeCurrent() + 60; // 1分後に再試行
      return false;
   }

   string body = CharArrayToString(result, 0, WHOLE_ARRAY, CP_UTF8);
   string lines[];
   int n = StringSplit(body, '\n', lines);

   ArrayResize(smt_eventTime, 0);
   ArrayResize(smt_eventTitle, 0);
   for(int i = 1; i < n; i++) // 0行目はヘッダー
   {
      // 最終行 "# server_time=1760702400 server_time_iso=..."：サーバーのUTC時刻
      if(StringFind(lines[i], "# server_time=") == 0)
      {
         long serverTime = StringToInteger(StringSubstr(lines[i], 14, 10));
         if(serverTime > 0)
         {
            smt_serverTime  = serverTime;
            smt_syncTick    = GetTickCount();
            smt_clockSynced = true;
         }
         continue;
      }
      string f[];
      if(StringSplit(lines[i], ',', f) < 8) continue;
      int k = ArraySize(smt_eventTime);
      ArrayResize(smt_eventTime, k + 1);
      ArrayResize(smt_eventTitle, k + 1);
      smt_eventTime[k]  = (datetime)StringToInteger(f[0]);      // Unix秒、UTC
      smt_eventTitle[k] = f[2] + " " + f[3] + ": " + SMT_AfterComma(lines[i], 7);
   }
   smt_nextDownload = TimeCurrent() + MathMax(SMT_RefreshMinutes, 15) * 60;
   Print("[SMT] calendar: ", ArraySize(smt_eventTime), " events loaded. UTC now ",
         TimeToString(SMT_Now(), TIME_DATE|TIME_MINUTES), ", broker clock is GMT",
         (SMT_BrokerGmtOffsetSeconds() >= 0 ? "+" : ""), DoubleToString(SMT_BrokerGmtOffsetSeconds() / 3600.0, 1));
   return true;
}

//--- 停止時間帯に発表があるあいだtrue。reasonにはどの発表かが入る
bool SMT_IsNewsTime(string &reason)
{
   reason = "";
   if(MQLInfoInteger(MQL_TESTER)) return false;   // テスターではネットワークが使えない
   if(TimeCurrent() >= smt_nextDownload) SMT_Download();

   datetime now = SMT_Now();
   for(int i = 0; i < ArraySize(smt_eventTime); i++)
   {
      if(now >= smt_eventTime[i] - SMT_MinutesBefore * 60 && now <= smt_eventTime[i] + SMT_MinutesAfter * 60)
      {
         reason = smt_eventTitle[i];
         return true;
      }
   }
   return false;
}

#include <SMT_NewsFilter.mqh>

void OnTick()
{
   string news;
   if(SMT_IsNewsTime(news))
   {
      Comment("News filter active: ", news);
      return;                       // ニュースの時間帯は新規エントリーしない
   }
   Comment("");
   // ... エントリーのロジック ...
}